# Akkana's .login file

# echo -n "[.login]"

#
# Reset PRIMES, and take any primes out of the prompt
# which was already set in .cshrc:
#
setenv PRIMES ""
set noglob
set prompt = `echo $prompt | sed s/\'//g`
unset noglob
# sed cmd strips out the final space, so put it back in:
set prompt = "$prompt "

#
# set up the terminal
#
# Many Suns (like netcom) don't have resize.
# So prepare to do something else if necessary.
which resize >& /dev/null
if ($status) then
    alias res 'echo "Assuming 57 rows ..."; stty rows 57'
else if ($term == "sun") then
    alias res 'set noglob; eval `resize -s \!*`'
else
    alias res 'set noglob; eval `resize \!*`'
endif

if ( -r $HOME/tcap) setenv TERMCAP $HOME/tcap

# if ($term == 'iris-ansi-net') set term='iris-ansi'
#if (! $?WINDOWID && $term != 'xterm' && ! ($term =~ iris*) && ! ($term =~ sun*)) then
#  set noglob
#  eval `tset -s -Q -m ':?vt100' `
#else if ((`uname -s` != IRIX) && ($term =~ iris*) ) then
#  set term=vt100
#  setenv TERM vt100
#endif
#set term = $TERM
stty echoe erase "^H" kill "^U" werase  intr "^C" eof "^D" susp "^Z"
# stty tabs hupcl ixon ixoff
if ($SHELL == "/bin/tcsh") then
    bindkey  backward-delete-word
endif

set mail = (0 /var/mail/akkana)
unset autologout
# setenv MORE -cs
#setenv EXINIT 'set ai wm=7 sm'
setenv ENSCRIPT -2r
# trn options: add -e -L for screen clearing (but it doesn't work right),
# omit -x and -X options for regular non-threaded rn
setenv RNINIT "-C12 -i=1 -M -s -x -X15X -m=u +q"

# Set the default X server in case we're here via rlogin:
# if ($?DISPLAY == 0) then
    if ($?REMOTEHOST) then
        setenv DISPLAY ${REMOTEHOST}:0
    else
        setenv DISPLAY :0
    endif
# endif

# Trim Procmail log
if (`who | grep akkana | wc -l` == "1" && \
   `hostname` == 'moon' && -x bin/trimproclog) then
  csh bin/trimproclog &
endif

# echo "."